传奇服务端188引擎物品穿戴触发范文详解

Gm版本库

功能：穿戴触发
格式：@TakeOnX   ;X代表物品位置
说明：人物或英雄穿上取下装备触发QF脚本

人物穿上触发： [@TakeOnX]
人物取下触发： [@TakeOffX]

英雄穿上触发： [@HeroTakeOnX]
英雄取下触发：[@HeroTakeOffX]
功能：穿戴触发
格式：@TakeOnEx  //不需要接物品位置
说明：人物或英雄穿上取下装备触发QF脚本

[@TakeOnEx]
[@TakeOffEx]

[@HeroTakeOnEx]
[@HeroTakeOffEx]


188引擎人物英雄逻辑的重要说明：  
       188引擎新增更新内容的英雄触发逻辑是：谁执行这个脚本谁就是主体！
       所需用到的变量都为第一人称，也就是用人物的变量！
       以前的逻辑为了leg和blue引擎的版本脚本转换方便暂时不动，保持原样！
--------------------------------------------------------------------------------------------------------------------
当前涉及到的命令为下面几个，以后的逻辑都是这个逻辑：
--------------------------------------------------------------------------------------------------------------------
英雄穿戴触发：
[@HeroTakeOnX]
[@HeroTakeOffX]
--------------------------------------------------------------------------------------------------------------------
英雄攻击触发：
[@HeroMagicAttack]         ;(魔法攻击触发)
[@HeroMagicStruck]        ;(被魔法攻击触发)
[@HeroAttack]         ;(攻击触发)
[@HeroStruck]        ;(被攻击触发)
--------------------------------------------------------------------------------------------------------------------

188引擎脚本变量大全【变量必须大写】       英雄变量如用在英雄穿戴触发和英雄攻击触发时,变量不用加H. 英雄登陆、英雄升级触发中需要加H.
比如 攻击触发中检测英雄身上的项链直接用<$NECKLACE>，在英雄登陆和英雄升级触发这些老引擎就有的功能脚本中就用<$H.NECKLACE>;
好处是：你写好了人物的带装备时的各种攻击buff脚本，准备写英雄段的时候直接复制粘贴过去就好了。不用去考虑什么乱七八糟的H.\HM.\HL.\HP.
记住这个逻辑：不论人物还是英雄，都是单个独立存在的人物！既然是独立的人物，那他进行的操作触发都应该是把他当作第一人称。这也就是很多玩家
把英雄和人物合称为双号，为什么叫双号，玩家都知道：主号是一个号，英雄也是一个号！
只要你把这个逻辑习惯了，写脚本就不要去考虑其他乱七八糟的，写好主号的之后直接复制粘贴到英雄那段就OK了！如果不是考虑到老引擎版本的转换方便，英雄登陆和升级触发都全给它改成这样了！

脚本范例：

;人物穿戴触发
;-------------------------------脚本区版主范例
[@TakeOn12]
#if
;没学护体神盾就到此结束了。需要其他检测写在上面
NOT CHECKMAGICNAME 护体神盾
#act
break
#if
checkitemw 魔血石(大) 1
NOT EQUAL S$护体神盾 生效
#act
MOV S$护体神盾 生效
SKILLLEVEL 护体神盾 = 6
sendmsg 6 <$CHARM>赋予了护体神盾强大的防御加成，当前为6级
break
;------------------------------------------------------------------脚本区版主范例
[@TakeOff12]
#if
NOT CHECKMAGICNAME 护体神盾
#act
break
#if
NOT checkitemw 魔血石(大) 1
EQUAL S$护体神盾 生效
#act
MOV S$护体神盾
SKILLLEVEL 护体神盾 = 4
sendmsg 5 护体神盾的力量已散去...当前为4级
break
;英雄穿戴触发；直接就复制人物穿戴的脚本，把检测技能的名字改一下就好了，其他的不用去改，直接用！多方便！
;------------------------------------------------------脚本区版主范例
[@HeroTakeOn12]
#if
;没学护体神盾就到此结束了。需要其他检测写在上面
NOT CHECKMAGICNAME 英雄护体神盾
#act
break
#if
checkitemw 魔血石(大) 1
NOT EQUAL S$英雄护体神盾 生效
#act
MOV S$英雄护体神盾 生效
SKILLLEVEL 英雄护体神盾 = 6
sendmsg 6 <$CHARM>赋予了护体神盾强大的防御加成，当前为6级
break
;-----------------------------------------------脚本区版主范例
[@HeroTakeOff12]
#if
NOT CHECKMAGICNAME 英雄护体神盾
#act
break
#if
NOT checkitemw 魔血石(大) 1
EQUAL S$英雄护体神盾 生效
#act
MOV S$英雄护体神盾
SKILLLEVEL 英雄护体神盾 = 4
sendmsg 5 护体神盾的力量已散去...当前为4级
break